/*********
  Rui Santos
  Complete instructions at
  https://RandomNerdTutorials.com/esp32-web-server-gauges/
    Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files.
  The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
********/

#define VERSION "2022_0605" // 10H50
// .rajout compteur 
// rajout mylogo_CI_90x68.jpg
// à suivre .port MCP23017
//#define VERSION "2022_0604" // 16H00

// rajout DS18B20 mesure

//#define VERSION "2022_0603"  // 18h47
// rajout Gauge Pression BMP085


/*  fichiers dans \data
favicon.png
index.html
script.js
style.css
*/
// probleme avec Board : ESP32  Doit DevkitV1 -> retour à Esp32 dev module
// modif espace  SPIFF  
//Used: C:\Users\Paul\AppData\Local\Arduino15\packages\esp32\hardware\esp32\2.0.1\libraries\WiFi
//C:\Users\Paul\Documents\Arduino\libraries\ESPAsyncWebServer\src/WebAuthentication.cpp:73: undefined reference to `mbedtls_md5_starts'
//see https://github.com/philbowles/ESPAsyncWebServer/issues/3
// modification déja incluses dans WebAuthentication.cpp, mais conditionelle via #ifdef EP32 
// rajout de
//#define ESP32


#include <Arduino.h>
#include <WiFi.h>
#include <ESPAsyncWebServer.h>
#include <AsyncTCP.h>
#include "FS.h"
#include "SPIFFS.h"
#include <Arduino_JSON.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <Adafruit_BMP085.h>
#include <Adafruit_Sensor.h>
#include <MCP23017.h>
#include <DHTesp.h>
#include <OneWire.h>
#include <DallasTemperature.h>

// set pin numbers
#define SCL 22            //ESP32 jaune --> SCL BMP085
#define SDA  21           //ESP32 fil vert --> SDA BMP085 
const int LedRouge =  5;      //  number of the LED Rouge pin

const char *ssid ="ON_AIR2021";  // attention aux  probleme avec guillemets (anglais) orientés !!!
const char *password ="cGT>1_@?LOdBqD6kd%s@v|.b5x^4PD|?s}uu*j4o)Uqpa|r1jftH+H>8_oG6}v4";

//const char *ssid ="ESP32_R";  // attention aux  probleme avec guillemets (anglais) orientés !!!
//const char *password ="12345678";

// Create AsyncWebServer object on port 80
AsyncWebServer server(80);

// Create an Event Source on /events
AsyncEventSource events("/events");

// Json Variable to Hold Sensor Readings
JSONVar readings;

int i,j,k;

// Timer variables
unsigned long lastTime = 0;
unsigned long timerDelay = 4000;

char temp[64];

#define MCP23017_ADDR 0x20
MCP23017 mcp = MCP23017(MCP23017_ADDR);
byte mcp_PA=0;
byte mcp_PB=0;
unsigned int mcp_PAB=0;
char MCP_Readchar[10];

char  Oled_Msg[64];  // up to 18 char en taille 1
#define OLED_ADDR 0x3C
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels
#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
#define SCREEN_ADDRESS 0x3C ///< See datasheet for Address; 0x3D for 128x64, 0x3C for 128x32
#define LOGO_HEIGHT   16
#define LOGO_WIDTH    16
#define paulfjujo_WIDTH 128
#define paulfjujo_HEIGHT 32
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// Set your Gateway IP address
IPAddress local_IP(192,168,0,104);
IPAddress gateway(192,168,0,254);
IPAddress subnet(255,255,255,0);
IPAddress primaryDNS(212,27,40,241);   //optional
IPAddress secondaryDNS(212,27,40,240);   //optional

char BMPOK=0;
char Presschar [10];

float temperatureC;
unsigned int Cpt=0;
float   p = 0.0;
float   t = 0.0 ;
float   h = 0.0 ;

#define DHTTYPE DHT22 ;  // DHT type (DHT11, DHT22)
int DHTPIN = 2 ;        // GPIO D2 <-- Broche du capteur  AM2302 
char Tempchar [10];
char Humidchar[10];

byte  nDevices = 0;
byte error=0;
byte address=0;

// Création des objets / create Objects
DHTesp dht;

// DS18B20 pin
const int oneWireBus = 4; 

  // Setup a oneWire instance to communicate with any OneWire devices
OneWire oneWire(oneWireBus);
DallasTemperature sensors(&oneWire);

// Create a sensor object
Adafruit_BMP085 bmp; // connect to ESP32 I2C (GPIO 21 = SDA, GPIO 22 = SCL)



 void check_if_exist_I2C()
{
  nDevices = 0;
  Serial.println(" ");
  for (address = 1; address < 127; address++ ) 
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();
    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address < 16)  Serial.print("0");
      Serial.print(address, HEX);
      switch (address)
            {
                case 0x20:  
                    Serial.println(" MCP23017 2x8 Bits I/O"); // de base + 7 autres
                     break;
                case 0x27:
                case 0x28:
                case 0x29:
                case 0x2A:
                    // case etc ..
                     Serial.println(" PCF8574 8bits I/O"); // de base + 7 autres
                    break;
                case 0x37:
                      Serial.println(" LCD 2119 2x16cars"); // de base + 7 autres
                    break;
                case 0x38:
                case 0x39:
                case 0x3A:
                case 0x3B:
                    // case etc ..
                      Serial.println(" PCF8574A 8bits I/O"); // de base + 7 autres
                    break;
                case 0x3C:
                      Serial.println( " OLED SSD1306");
                      break;
                case 0x53:
                       Serial.println(" ADXL345 board");
                        break;
                case 0x57:
                        Serial.println(" EEPROM 512bytes");
                        break;
                case 0x68:
                        Serial.println(" RTC DS3231");
                        break;
                case 0x77:
                        Serial.println(" BMP 085 Pression");
                        break;
                default:
                        Serial.println(" non reconnue");
                        break;
           } //switch
      nDevices++;
    }
    delay(10);
  } //for loop
  if (nDevices == 0)
    Serial.println("No I2C devices found");
  else
    Serial.printf("Trouve %3d devices sur le Bus I2C\r\n",nDevices);
  delay(200);       
}

// Get Sensor Readings and return JSON object
String getSensorReadings(){
     t = dht.getTemperature();
   readings["temperature"] = String(t);
       h=dht.getHumidity();
    readings["humidity"] =  String(h);
    readings["pression"] =  String(p);
  //  readings["MCP23017"]=String( mcp_PB);
  //  readings["compteur"] =  String(Cpt);
   readings["ows1"]=String(temperatureC);
  String jsonString = JSON.stringify(readings);
  return jsonString;
}

// Initialize SPIFFS
void initSPIFFS() {
  if (!SPIFFS.begin()) {
    Serial.println("An error has occurred while mounting SPIFFS");
  }
  Serial.println("SPIFFS mounted successfully");
}

// Initialize WiFi

void initWiFi() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  Serial.print("Connecting to WiFi ..");
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print('.');
    delay(1000);
  }
  Serial.println(WiFi.localIP());
}


void setup() {
  delay(1000);
  // Serial port for debugging purposes
  Serial.begin(115200);
  delay(1000);
  pinMode(LedRouge, OUTPUT); // initialize the LED pin as an output
  Serial.println("\r\n_r\n");
  Serial.print(" ESP32_AsynWebserver_AM2302_Gauges_OLED_etc_2022-06_VSC_");
  Serial.println(VERSION);
  Serial.println(" ESP32 Vroom 32 DevkitV1  (Rouge sur COM 56) ou (Bleu sur COM 57) ");
  Serial.println(" Led Rouge sur D5  ");
  Serial.println(" DHT11-AM2302 sur D2 ");
  Serial.println(" Sonde temper.OWS  DS18B20 sur D4 ");
  Serial.println(" I2C Bus sur   D21 (SDA)  et D22 (SCL) "); 
  Serial.println(" BMP085, OLED SSD1306 et MCP23017 sur le bus I2C");
  delay (500);
  Serial.println(" Recherche devices présents  sur le bus I2C ");
  delay(2000);
   Wire.begin(SDA,SCL); // pin on ESP32
   check_if_exist_I2C();
   Serial.println("\r\n .. Fin de test I2C bus \r\n");
 
   sensors.begin();
   delay(1000);
   
   Serial.printf(" Cpt=%5d\r\n",Cpt);
  
 //---- Pressure sensor BMP085 ---------------- 
  // Initialisation 
  if ( !bmp.begin() )
   {
    Serial.println(" BMP085 BAD!");
    delay(2000);
    BMPOK=0;
   } 
   else 
   {
    Serial.println(" BMP085 OK");
    BMPOK=1;
  } 
  
   if (BMPOK==1)
   {
      p = bmp.readPressure() / 100.0F; 
      Serial.printf(" Press.% 5.0f mBar \r\n",p); 
    }
    else
    {
      p=999.99; 
    }
    sensors.requestTemperatures();
    temperatureC = sensors.getTempCByIndex(0);
    Serial.print(" DS18B20=");
    Serial.print(temperatureC);
    Serial.println("° C");
   
  
// --- MCP23017 ----------------------
// https://github.com/blemasle/arduino-mcp23017
   Serial.println("  MCP23017 at  @0x20 ");
   mcp.init();
   Serial.println(" Active le PORT A du MCP , en sorties"); 
  //  setGPIOAMode(0);
   mcp.portMode(MCP23017Port::A, 0);  
    Serial.println(" Active le PORT B du MCP , en entrees");
   mcp.portMode(MCP23017Port::B, 0b11111111); //Port B as input
   mcp.writeRegister(MCP23017Register::GPIO_A, 0x00);  //Reset port A 
   mcp.writeRegister(MCP23017Register::GPIO_B, 0x00);  //Reset port B
   // GPIO_B reflects the reverse logic as the input pins state
   mcp.writeRegister(MCP23017Register::IPOL_B, 0xFF);
  
  //----- DHT11 AM2302 Sensor ----------------
   dht.setup(DHTPIN,DHTesp::DHT22);
   delay(1000);

   t = dht.getTemperature();
    if (isnan(t)) 
    {
    snprintf(Tempchar,6,"%s\t"," ???");
     }
     else
     {
    snprintf(Tempchar,6,"%3.2f\t",t);
    Serial.print(F(" DHT11 Temp.: ")); 
    Serial.println(Tempchar);
     }

    h=dht.getHumidity();
    if (isnan(h)) 
    {
     snprintf(Humidchar,6,"%s\t"," ???");
    }
    else
    {
     snprintf(Humidchar,6,"%2.2f\t",h);
    }
    Serial.print(F(" Humid : ")); 
    Serial.println(Humidchar);

    //----------- OLED SSD1306 ----------------  

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS))
  {
    Serial.println(F("SSD1306 allocation failed"));
    delay(2000);
    for(;;); // Don't proceed, loop forever
  }
  else
  Serial.println(F("SSD1306 allocation OK"));
  
   display.clearDisplay();
   display.setTextSize(1);             // Normal 1:1 pixel scale
   display.setTextColor(SSD1306_WHITE);        // Draw white text
   display.setCursor(0,0);             // Start at top-left corner
   delay(2000); // Pause for 2 seconds
   display.clearDisplay();  // Clear the buffer
      
     delay(1000);



   Serial.println("\r\n Init Wifi");

   initWiFi();
  
   display.setTextSize(1);             // Normal 1:1 pixel scale
   display.setTextColor(SSD1306_WHITE);        // Draw white text
   display.setCursor(0,0);             // Start at top-left corner
   display.print(F("IP Adresse        "));
   display.setCursor(0,8);             // Start at top-left corner
   display.print( WiFi.localIP());
   display.setCursor(0,16);
   display.print( WiFi.macAddress());
   display.display();
   delay(2000);

  
  //Serial.println("\r\nInit SPIFFS");
  initSPIFFS();

  // Web Server Root URL
  server.on("/", HTTP_GET, [](AsyncWebServerRequest *request)
  {
    request->send(SPIFFS, "/index.html", "text/html");
  });

  server.serveStatic("/", SPIFFS, "/");

  // Request for the latest sensor readings
  server.on("/readings", HTTP_GET, [](AsyncWebServerRequest *request){
    String json = getSensorReadings();
    request->send(200, "application/json", json);
    json = String();
  });

  events.onConnect([](AsyncEventSourceClient *client){
    if(client->lastId()){
      Serial.printf("Client reconnected! Last message ID that it got is: %u\n", client->lastId());
    }
    client->send("hello!", NULL, millis(), 5000);
  });
  server.addHandler(&events);

  // Start server
  server.begin();
}

void loop() {
  if ((millis() - lastTime) > timerDelay) {
    // Send Events to the client with the Sensor Readings Every 10 seconds
    events.send("ping",NULL,millis());
    events.send(getSensorReadings().c_str(),"new_readings" ,millis());
    lastTime = millis();
   
  }
  else
   {
 
    display.clearDisplay();
    display.setCursor(0,0); 
    display.print(F("Compteur          ")); 
    display.setCursor(70,0); 
    snprintf(Oled_Msg,6,"% 5d",Cpt);
    display.print(Oled_Msg);
    display.display();
 
    Serial.printf(Oled_Msg);
    if (BMPOK==1) p = bmp.readPressure() / 100.0F;  else p=999.99; 
    Serial.printf("  BMP085 P.% 5.0f mBar, ",p); 

    h=dht.getHumidity();
    if (isnan(h)) 
    {
     snprintf(Humidchar,6,"%s\t"," ???");
    }
    else
    {
     snprintf(Humidchar,6,"%2.2f\t",h);
    }
    Serial.print(F(", Humid: ")); 
    Serial.print(Humidchar);

    display.setCursor(0,8); 
    display.print(F("AM2302 Humi  ")); 
    display.setCursor(76,8); 
    display.print(Humidchar);
    display.display();
    
    t = dht.getTemperature();
    if (isnan(t)) 
    {
    snprintf(Tempchar,6,"%s\t"," ???");
     }
     else
     {
    snprintf(Tempchar,6,"%3.2f\t",t);
    Serial.print(F(", Temp: ")); 
    Serial.print(Tempchar);
    display.setCursor(0,16); 
    //               123456789012345678
    display.print(F("AM2302 Temp       ")); 
    display.setCursor(76,16); 
    display.print(Tempchar);
    }

   

    display.setCursor(0,24); 
    display.print(F("BMP085 P.    ")); 
    display.setCursor(70,24); 
    display.print(p);
    display.display();
   
    mcp_PA= mcp.readPort(MCP23017Port::A);
    mcp_PB= mcp.readPort(MCP23017Port::B);
    mcp.writePort(MCP23017Port::A, i & 0x00FF);
 
    sensors.requestTemperatures();
    temperatureC = sensors.getTempCByIndex(0);
    Serial.print(", DS18B20=");
    Serial.print(temperatureC);
    Serial.println("° C");
    if ((Cpt & 1)==1) digitalWrite(LedRouge,HIGH); else digitalWrite(LedRouge,LOW);    
    Cpt++;
    delay(1000);
   
  }
 }
/*
ets Jun  8 2016 00:22:57

rst:0x1 (POWERON_RESET),boot:0x17 (SPI_FAST_FLASH_BOOT)
configsip: 0, SPIWP:0xee
clk_drv:0x00,q_drv:0x00,d_drv:0x00,cs0_drv:0x00,hd_drv:0x00,wp_drv:0x00
mode:DIO, clock div:2
load:0x3fff0030,len:1284
load:0x40078000,len:12808
load:0x40080400,len:3032
entry 0x400805e4

_r<LF>
 ESP32_Rouge_I2C_Mac_adress_DHT11_MCP23017_DS18B20_VSC_2022_0603
 ESP32 Vroom 32 DevkitV1  (Rouge) sur COM 57 
 Led Rouge sur D5  
 DHT11-AM2302 sur D2 
 Sonde temper.OWS  DS18B20 sur D4 
 I2C Bus sur   D21 (SDA)  et D22 (SCL) 
 I2C adresses 7 bits devices 
 
I2C device found at address 0x20 MCP23017 2x8 Bits I/O
I2C device found at address 0x3C OLED SSD1306
I2C device found at address 0x77 BMP 085 Pression
Trouve   3 devices sur le Bus I2C

 .. Fin de test I2C bus 

 BMP085 OK
 Cpt=    0
 Press.  986 mBar 
  MCP23017 at  @0x20 
 Active le PORT A du MCP , en sorties
 Active le PORT B du MCP , en entrees
 Humid :  ???  
SSD1306 allocation OK

 Init Wifi


 ... la suitre sur l'ecran OLED

*/